tetradTest.nb

For the given tetrad, this notebook computes the left-hand-side of the equations of motion within the (a) non-Lorentz-covariant and the (b) Lorentz-covariant form of F(T) gravity theory.

The notebook can be considered as supplementary material to arXiv:1609:07465 by A. DeBenedictis and S. Ilijic.

Date[]

1. Coordinates and the tetrad

The four specetime coordinates and the number of dimensions:

cu={t,r,ϑ,φ};
ndim=Length[cu];

Tetrad (first index is the tetrad-up-index, second index is the spacetime-down-index, therefore  variable name ends with Ud):

hUd=(({{A[r], 0, 0, 0}, {0, B[r], 0, 0}, {0, 0, r, 0}, {0, 0, 0, r Sin[ϑ]}}));

The tetrad with first (tetrad) index up and second (spacetime) index down:

hDu=Transpose@Inverse[hUd];

The transformation rule that enforces the flat spacetime limit:

flatRule={A->Function[r,1],B->Function[r,1]}

The determinant of the tetrad matrix:

dethUd=Det[hUd]//Simplify

2. Metric compatibility

The tetrad gives raise to the following metric:

mink=-IdentityMatrix[ndim];mink[[1,1]]*=-1;
gdd=Transpose[hUd].mink.hUd//Simplify;
gdd//MatrixForm

The flatRule transforms the metric tensor into its flat-space limit:

gdd/.flatRule//MatrixForm

The up-up index meric tensor:

guu=Inverse[gdd];
guu//MatrixForm

3. Torsion tensor first part (((T^((0)))^
), assuming spin connection = 0)

Torsion tensor:

tmpUdd=Transpose[D[hUd,#]&/@cu];
torsion0Udd=tmpUdd-Transpose[tmpUdd,{1,3,2}]//Simplify;
torsion0udd=Transpose[hDu].torsion0Udd//Simplify;
MatrixForm/@%

4. Spin connection (ω, with “tracking factor” σ)

Calculation of the spin connection as proposed by Krssak and Saridakis (arXiv:1510.08432):

omgUDd=Array[omg,{4,4,4}];
omgUdd=Transpose[Transpose[hUd].Transpose[omgUDd]]/.flatRule;

torUdd=torsion0Udd+(Transpose[omgUdd,{1,3,2}]-omgUdd)//Simplify;

omgEqns1=0==#&/@Flatten[torUdd/.flatRule];

omgEqns2=0==#&/@Flatten[mink.omgUDd+Transpose[mink.omgUDd]];

omgsol=Solve[Join[omgEqns1,omgEqns2],Flatten[omgUDd]];

Spin connection omega multiplied by the "tracking-parameter" sigma (first index is tetrad-up, second is tetrad-down, third is spacetime-down):

omegaUDd=σ omgUDd/.omgsol[[1]]//Simplify

Testing that the four matrices are antisymmetric:

MatrixForm/@Transpose[mink.omegaUDd,{2,3,1}]

Spin connection (first two indices are tetrad-up, third is spacetime-down):

omegaUUd=Transpose[mink.Transpose[omegaUDd]]

Some other variants for later convenience

omegaUdd=Transpose[Transpose[hUd].Transpose[omegaUDd]];
tmpuud=Transpose[hDu].Transpose[Transpose[hDu].Transpose[omegaUUd]];
omegau=Table[Sum[tmpuud[[α,μ,α]],{α,4}],{μ,4}]//Simplify

5. Complete torsion tensor (T, now involves spin connection)

This is now the complete torsion tensor which involves the spin connection:

torsionUdd=torsion0Udd+(Transpose[omegaUdd,{1,3,2}]-omegaUdd)//Simplify;
torsionudd=Transpose[hDu].torsionUdd//Simplify

torsionddd=gdd.torsionudd//Simplify;
torsionuuu=Transpose[guu.Transpose[torsionudd.guu]]//Simplify;

torsiond=Apply[Plus,#]&/@Transpose[torsionudd,{2,1,2}]//Simplify

6. Contortion (K)

This is the contortion tensor:

contortionddd=(Transpose[gdd.torsionudd,{1,3,2}]+Transpose[gdd.torsionudd,{2,1,3}]+Transpose[gdd.torsionudd,{3,1,2}])/2//Simplify;
contortionudd=guu.contortionddd//Simplify;
MatrixForm/@contortionudd

7. Modified torsion or “superpotential” (S)

This is the modified torsion tensor or the superpotential:

modtorsionddd=(Transpose[contortionddd,{2,3,1}]+Transpose[Outer[Times,gdd,torsiond],{1,2,3}]-Transpose[Outer[Times,gdd,torsiond],{1,3,2}])//Simplify;
MatrixForm/@%

modtorsionuuu=Transpose[guu.Transpose[guu.modtorsionddd.guu]]//Simplify;
modtorsionDuu=mink.hUd.modtorsionuuu//Simplify;

8. Torsion scalar (T)

This is the torsion scalar with the spin-connection-tracking-factor sigma:

torsionscalar=Sum[torsionuuu[[a,b,c]]modtorsionddd[[a,b,c]],{a,ndim},{b,ndim},{c,ndim}]/2//Simplify

Setting sigma=0 gives the torsion scalar used in the standard TEGR and in the non-covariant form of f(T)-gravity:

torsionscalar/.{σ->0}

Setting sigma=1 gives the torsion scalar used in the covariant form of F(T)-gravity.

torsionscalar/.{σ->1}

9. Equations of motion for f(T) gravity

These are the terms of the left-hand-side of the equation of motion (see 1609:07465 eq. (10)):

foftEomTerm1aDu=foft2 modtorsionDuu.(D[torsionscalar,#]&/@cu);
foftEomTerm1bDu=(dethUd^(-1))foft1 Table[Sum[(D[dethUd modtorsionDuu,#]&/@cu)[[ν,a,μ,ν]],{ν,4}],{a,4},{μ,4}];
foftEomTerm2Du=-foft1 Table[ Sum[(torsionUdd.Transpose[hDu])[[c,ν,a]]modtorsionDuu[[c,ν,μ]],{c,4},{ν,4}],{a,4},{μ,4}];
foftEomTerm3Du=foft0 hDu/2;
foftEomTerm4Du=foft1 Table[ Sum[omegaUDd[[c,a,ν]]modtorsionDuu[[c,ν,μ]],{c,4},{ν,4}],{a,4},{μ,4}];

The left-hand-side of the equations of motion:

foftEomLhsDu=foftEomTerm1aDu+foftEomTerm1bDu+foftEomTerm2Du+foftEomTerm3Du+foftEomTerm4Du;
foftEomLhsdu=Transpose[hUd].foftEomLhsDu//Simplify;

In static spherical symmetry one expects diagonal energy-momentum tensor and therefore also the left-hand-side of the equations of motion (left plot of the matrix is the non-covariant form, right plot is the covariant form):

GraphicsArray[{MatrixPlot[foftEomLhsdu/.{σ->0}//Simplify],MatrixPlot[foftEomLhsdu/.{σ->1}//Simplify]}]

foftEomLhsdu/.{σ->0}//Simplify

foftEomLhsdu/.{σ->1}//Simplify

The difference between the non-covariant and the covariant form of the left-hand-side of the equations of motion:

(foftEomLhsdu/.{σ->0})-(foftEomLhsdu/.{σ->1})//Simplify